Dir
Tableau de noms de fichiers = Dir ( Répertoire AS String
[ , Motif As String , Filtre As Integer ] ) As String[]
Retourne un tableau de chaînes de caractères qui contient les noms des fichiers situés dans
Répertoire et qui correspondent au
Motif et au
Filtre.
Le motif peut contenir les même caractères génériques que l'opérateur
LIKE. Si aucun motif n'est spécifié, tous les fichiers et répertoires sont retournés.
Le filtre spécifie le type de fichiers à retourner.
Le filtre peut être une des valeurs suivantes :
-
gb.File pour retourner uniquement les fichiers.
-
gb.Directory pour retourner uniquement les répertoires.
-
gb.File + gb.Directory pour retourner les deux à la fois.
Si
Filtre n'est pas spécifié, tous les fichiers et répertoires sont retournés.
Les noms de fichier retournés sont relatifs au répertoire de recherche. Ils ne contiennent pas le chemin du répertoire de recherche.
Exemples
' Affiche les fichiers images png contenus dans un répertoire, par ordre alphabétique.
SUB AfficheRepertoire(Repertoire As String)
Dim Fichier As String
For Each Fichier In Dir(Repertoire, "*.png").Sort()
Print Fichier
Next
End
' Affiche tous les fichiers non cachés dans le répertoire de l'utilisateur.
Dim fileName AS String
For Each fileName In Dir(User.Home, "[^.]*")
Print fileName
Next
' Affiche le nom des images png et jpeg présents dans le répertoire de l'utilisateur.
Dim directory As String
Dim files As String[]
Dim fileName As String
directory = User.Home
files = Dir(directory, "*.png")
files.Insert(Dir(directory, "*.jpg"))
files.Insert(Dir(directory, "*.jpeg"))
For Each fileName In files
Print fileName
Next
' Affiche seulement les fichiers présents dans le répertoire de l'utilisateur.
Dim fileName As String
For Each fileName In Dir(User.Home, "*", gb.File)
Print fileName
Next
' Affiche seulement les sous-répertoires présents dans le répertoire de l'utilisateur.
Dim directoryName As String
For Each directoryName In Dir(User.Home, "*", gb.Directory)
Print directoryName
Next
' Affiche tous les sous-répertoires visibles dans le répertoire de l'utilisateur.
Dim directoryName As String
For Each directoryName In Dir(User.Home, "[^.]*", gb.Directory)
Print directoryName
Next
Voir aussi