Method Declaration
Procedures
[ FAST [ UNSAFE] ] [ STATIC ] { PUBLIC | PRIVATE } { PROCEDURE | SUB }
Identifier
(
[ [ BYREF ] Parameter AS Datatype [ , … ] ] [ , ]
[ OPTIONAL [ BYREF ] Optional Parameter AS Datatype [ , … ] ] [ , ] [ ... ]
)
...
END
This declares a procedure, i.e. a method that returns nothing.
The
END keyword indicates the end of the procedure.
Functions
[ FAST [ UNSAFE] ] [ STATIC ] { PUBLIC | PRIVATE } { FUNCTION | PROCEDURE | SUB }
Identifier
(
[ [ BYREF ] Parameter AS Datatype [ , … ] ] [ , ]
[ OPTIONAL [ BYREF ] Optional Parameter AS Datatype [ , … ] ] [ , ] [ ... ]
)
AS Datatype
...
END
This declares a function, i.e. a method that returns a value.
The
END keyword indicates the end of the function.
The datatype of the return value must be specified.
These declarations must be written on a unique line. They are separated here so that the syntax is readable.
Returning a value from a function
Use the
RETURN keyword to terminate the function and pass the return value back to the caller.
Example
Public Sub Main()
Print Calc(0);; Calc(0.5);; Calc(1)
End
Function Calc(fX As Float) As Float
Return Sin(fX) * Exp(- fX)
End
0 0.290786288213 0.309559875653
Method Access
The method is accessible everywhere in the class it is declared.
-
If the
PUBLIC keyword is specified, it is also accessible to the other classes having a reference to an object of this class.
-
If the
STATIC keyword is specified, the method can only access to the static variables of the class.
Method Arguments
All method arguments are separated by commas.
-
If the
OPTIONAL keyword is specified, all parameters after the keywords are optional. You can specify a default value after the parameter declaration by using the equal sign.
Example
STATIC PUBLIC PROCEDURE Main()
...
PUBLIC FUNCTION Calc(fA AS Float, fB AS Float) AS Float
...
PRIVATE SUB DoIt(sCommand AS String, OPTIONAL bSaveIt AS Boolean = TRUE)
...
STATIC PRIVATE FUNCTION MyPrintf(sFormat AS String, ...) AS Integer
-
If the parameters list end with
..., then the method can take extra arguments. Every additional argument passed to the method is accessible with the Param class.
Passing extra arguments with "..."
Sinds 3.6
We can either pass a known number of arguments through
Function1() to
Function2() using the
... keyword
or it can be used as a
variadic expression using the
Param class to pass any number of any datatype.
The
... keyword is used to transmit all the extra arguments to the function accepting them.
Example 1
Passing a known number of arguments to another function.
Sub Main()
PassSomeArgs("warning", "format description" , "info")
End
Sub PassSomeArgs(sType As String, ...)
' Do something with sType and pass all the other args to the next function.
Print "Got message type " & sType
PrintMessage(sType, ...)
End
Sub PrintMessage(sType as String, sFormat as String, sInfo as String)
' Do some stuff with the known number of arguments passed.
End
Example 2
Using Param class to pass any number of arguments of any datatype (variadic)
Sub Main()
ProcessVariadic("warning", "format description" , "info", -1)
End
Sub ProcessVariadic(...)
' Here we use the Param class to access and print all arguments supplied via "..."
' (you must take care of variable types if they are unknown)
Print "There are " & Param.Count & " arguments"
Dim iType As Integer
For Each vVar As Variant In Param.All
iType = TypeOf(vVar)
If iType = gb.String then
Print "Arg is a String: " & vVar
Else If iType = gb.Integer then
Print "Arg is Integer: " & Str(vVar)
Endif
Next
End
Arguments Passed By Reference
When the
BYREF keyword is specified, the argument must be an assignment expression that will be modified by the called function.
Example
SUB ConvPixelToCentimeter(BYREF Value as Float, Dpi AS Integer)
Value = Value / Dpi * 2.54
END
PUBLIC SUB Main()
DIM Size AS Float
Size = 256
ConvPixelToCentimeter(BYREF Size, 96)
PRINT Size
END
The
BYREF keyword must be specified both at function declaration and at function call!
If you do not specify
BYREF at function call, then the argument is passed by value, even if
BYREF was specified at function declaration.
In other words: the called function
allows an argument to be passed by reference, whereas the caller
decides it.
Just In-Time Compilation
Sinds 3.2
If the
FAST keyword is used, then the method will be optimized by the
Just In Time Compiler.
Sinds 3.12
Moreover, if the
UNSAFE keyword is specified, the
Just In Time Compiler will use unsafe but faster code.
See also