lang • split

Split

StringArray = Split ( String [ , Separators , Escape , IgnoreVoid , KeepEscape ] )

Split a string into substrings delimited by separators and escape characters.

  • String is the string to split.

  • Separators is a list of separator characters.

  • Escape is an escape character. Any separator characters enclosed between two escape characters are ignored in the splitting process. If Escape contains two characters, then the first is the starting escape character, and the second the ending one.

  • IgnoreVoid is a boolean that tells Split() not to return void elements.

  • KeepEscape is a boolean that tells to keep the encountered escape characters in the returned strings.

This function returns a string array filled with each detected substring. Separators and escape characters are not returned.

By default, the comma character is the separator, and there are no escape characters.

If a string contains escape characters, then these escape characters must be duplicated.

Separator and escape characters are just single one-byte ASCII characters. You cannot use this function to split a string with a non-ASCII character or a another string.

For example: Split(MyString, "\r\n") will split MyString by using "\r" or "\n" as separator, but not the full string "\r\n".

Examples

Dim Elt As String[]
Dim Sb As String

Elt = Split(" Gambas Almost Means BASIC  !\n'Do you agree ?'", " \n", "'")

For Each Sb In Elt
  Print "("; Sb; ") ";
Next
Print
() (Gambas) (Almost) (Means) (BASIC) () (!) (Do you agree ?)
Elt = Split(" Gambas Almost Means BASIC  !\n'Do you agree ?'", " \n", "'", True)

For Each Sb In Elt
  Print "("; Sb; ") ";
Next
Print
(Gambas) (Almost) (Means) (BASIC) (!) (Do you agree ?)
Elt = Split("(Gambas) (Almost) (Means) (BASIC) (!) (Do you agree ?)", " ", "()")

For Each Sb In Elt
  Print Sb; ".";
Next
Print
Gambas.Almost.Means.BASIC.!.Do you agree ?.

See also